Höhere Mathematik sehen und verstehen, 
Haftendorn, Riebesehl, Aug. 2021

Kreis mit rationalen Béziersplines, 
Version Anregung  5.2 mit N2=(-1,0)

Bernsteinpolynome

b[0,t_]:=(((1-t))^3);
b[1,t_]:=3t(((1-t))^2); 
b[2,t_]:=3(t^2)(1-t);b[3,t_]:=(t^3)

Herleitung einer Parameterdarst. für den Kreis

Vorgehen: Eine beliebige Gerade durch einen bekannten Punkt schneidet  den Kreis. 
Die Steigung t dieser Geraden eignet sich als Parameter.

Kreis     (x^2)+(y^2) ==(r^2)

kreis=ContourPlot[(x^2)+(y^2) ==9,{x,-3,3},{y,-3,3}, AspectRatio->1, ContourStyle->{Red}];

Manipulate[Show[{kreis,Plot[t(x+r)/.r->3,{x,-3,3},AxesOrigin->{0,0},
Axes->True, PlotRange->{{-3,3},{-3,3}}]}],
{{t,0.5},-10
,10}]

Solve[{(x^2)+(y^2)==(r^2), y==t (x+r)},{x,y}]

Definition rationaler Bézierspline-Basis

Rw=.

Rw[i_,t_]:=((ww[i] b[i,t])/(Sum[ww[j] b[j,t],{j,0,3}])); 
Rw[i,t]

Bestimmung der Gewichte aus der Parameterdarstellung

x[t_]:=((r-r (t^2))/(1+(t^2)));y[t_]:=((2 r t)/(1+(t^2))) (*Kreis, Parameterdarst. umgehrt wie in Buch*)

Die Gewichte müssen aus dem Nenner  mit Koeffizientenvergleich bestimmt werden

nenner=Sum[ww[j] b[j,t],{j,0,3}]

CoLi=CoefficientList[nenner,t]

Solve[CoLi=={1,0,1,0},{ww[0],ww[1],ww[2],ww[3]}]

Also sind die Gewichte  für den Kreis:

W={1,1,(4/3),2};

w[i_]:=W[[i+1]]

nenner=Sum[w[i] b[i,t],{i,0,3}]//Simplify   (* wie erwartet*)

Aufbau der Bernsteinpolynome in der rationalen Version

Verwendung der Gewichte auch im Zähler der rationalen Bézierbasis

R[i_,t_]:=((w[i] b[i,t])/nenner)

{R[0,t],R[1,t],R[2,t],R[3,t]}

Vergleichende Bilder

alle=Plot[{R[0,t],R[1,t],R[2,t],R[3,t],b[0,t],b[1,t],b[2,t],b[3,t]},{t,0,1}]
nurRat=Plot[{R[0,t],R[1,t],R[2,t],R[3,t]},{t,0,1}]

Steuerpunkte für den Kreis

Punkte (Variabel gelassen)

P={{Axx,Ayy}, {Bxx,Byy},{Cxx,Cyy},{Dxx,Dyy}}

Kreis Parameterdarstellung in dieser Version

x[t_]:=((r (1-(t^2)) )/((1+(t^2)))); y[t_]:=((2r t)/((1+(t^2))));

Berechnung der Steuerpunkte im Gerüst für den Kreis

Berechnung x-Koordinaten

xwerte=Axx R[0,t]+Bxx R[1,t]+Cxx R[2,t]+Dxx R[3,t]//Simplify//Numerator

xco=CoefficientList[xwerte,t]

Eq=xco=={r,0,-r ,0};

solx=Solve[Eq,{Axx,Bxx,Cxx,Dxx}]

Berechnung y-Koordinaten

ywerte=Ayy R[0,t]+Byy R[1,t]+Cyy R[2,t]+Dyy R[3,t]//Simplify//Numerator

yco=CoefficientList[ywerte,t]

Eqy=yco=={0,2r,0,0};

soly=Solve[Eqy,{Ayy,Byy,Cyy,Dyy}]

Steuerpunkte sind

{A={r,0},B={r,(2/3)r},Cc=((r/2),r),Dd={0,r}}  
(*Das gerüst ist gespiegelt gegenüber die Buchdarstellung*))

x[t_]:=((r (1-(t^2)) )/((1+(t^2)))); y[t_]:=((2r t )/((1+(t^2))))

Parameterdarstellung mit rationalen Béziersplines (wie erwartet)

Axx R[0,t]+Bxx R[1,t]+Cxx R[2,t]+Dxx R[3,t]/.solx//Simplify

Ayy R[0,t]+Byy R[1,t]+Cyy R[2,t]+Dyy R[3,t]/.soly//Simplify

{A={r,0},B={r,(2/3)r},Cc={(r/2),r},Dd={0,r}}

Das ist also das Gerüst für Anregung 5.2. mit N2=(-1,0)

Viertelkreis=ParametricPlot[{x[t],y[t]}/.r->3,{t,0,1},
PlotStyle->{ RGBColor[0,0.5,1], Thickness[0.01]}];

r=3;
Show[Graphics[{Thickness[0.02],PointSize[0.04],  RGBColor[0.5,0.5,0.8],Point[{{r,0},{r,((2 r)/3)},{(r/2),r},{0,r}}],Line[{{r,0},{r,((2 r)/3)},{(r/2),r},{0,r}}]}
],Viertelkreis] (*von rechts unten nach links oben*)
r=.

GeoGebra-Dateien dazu  
echte-Trisektrix--andererKreis.ggb