Exakte Lösungen zum Pendel

Buch:Höhere Mathematik sehen und verstehen, Haftendorn, Riebesehl, Dammer, 
Springer Spektrum, Feb. 2021
Datei PendelExakt.nb zu Abschnitt 4.3.4.1 Seite 300, Abb. 4.10

Lösen der Differentialgleichung

DSolve[ϕ''[t]==-Sin[ϕ[t]],ϕ[t],t]

Wenn man sich die Konstanten C[1] und C[2] genauer ansieht, erkennt man, dass es so besser ist: k=(4/(2+C(1))), C(2)=-(Subscript[t, 0]), dabei verschiebt (Subscript[t, 0]) nur den Start der Zeit, also ist im Folgenden (Subscript[t, 0])=0 gesetzt.

Bilder der Lösungsfunktion ϕ(t)

Plot[2 JacobiAmplitude[(t/(Sqrt[k])),k]/.k->1.001,{t,0,30}]

Bilder im Phasenraumdiagramm

ParametricPlot[{2 JacobiAmplitude[(t/(Sqrt[k])),k],D[2 JacobiAmplitude[(t/(Sqrt[k])),k],t]}/.k->1.001//Evaluate,{t,0,30}]

ParametricPlot[{2 JacobiAmplitude[(t/(Sqrt[k])),k],D[2 JacobiAmplitude[(t/(Sqrt[k])),k],t]}/.k->1.1//Evaluate,{t,0,30}]

ParametricPlot[{2 JacobiAmplitude[(t/(Sqrt[k])),k],D[2 JacobiAmplitude[(t/(Sqrt[k])),k],t]}/.k->0.999//Evaluate,{t,0,30}]

ParametricPlot[{2 JacobiAmplitude[(t/(Sqrt[k])),k],D[2 JacobiAmplitude[(t/(Sqrt[k])),k],t]}/.k->0.9//Evaluate,{t,0,12},AxesOrigin->{0,0}]

Phasenraumdiagramm mit vielen Kurven

Der Parameter k ist variiert worden. t läuft von 0 bis 4. Man erkennt schön, dass man in dieser Zeit verschieden weit kommt (verschieden viele volle Umdrehungen schafft)

ParametricPlot[Table[{2 JacobiAmplitude[(t/(Sqrt[k])),k],D[2 JacobiAmplitude[(t/(Sqrt[k])),k],t]},{k,0.2,1.8,0.2}]//Evaluate,{t,0,4},AxesOrigin->{0,0}]

Wir geben statt k die Start- (Anschubs-)Winkelgeschwindigkeit ω vor.

Den Zusammenhang müssen wir hier erst klären: dieser Ableitungswert ist die Start-Winkelgeschwindigkeit ω.

D[2 JacobiAmplitude[(t/(Sqrt[k])),k],t]/.t->0

Wir lösen nach k auf und ersetzen. ω in gleichen Abständen von 0.2 bis 3.0 sorgt nun für gleichabständige Startpunkte der Kurven auf der ϕ’-Achse.

ParametricPlot[Table[{2 JacobiAmplitude[(t/(Sqrt[k])),k],D[2 JacobiAmplitude[(t/(Sqrt[k])),k],t]}/.k->(4/(ω^2)),{ω,0.2,3,0.2}]//Evaluate,{t,0,4},AxesOrigin->{0,0},PlotStyle->Thickness[0.005],BaseStyle->FontSize->20,Ticks->{Table[n π/2,{n,1,6}],Automatic}]